/usr/share/polygen/ita/antani.grm is in polygen-data 1.0.6.ds2-14build1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 | I ::= "title: Antanizer (real)\n"
^ "author: Velenux <velenux@karma.oltrelinux.com>\n"
^ "language: italian\n"
^ "status: mature\n"
^ "topic: misc\n"
^ "audience: anybody\n"
^ "disclaim: usare con moderazione\n"
^ "created: 12/09/2003"
;
S ::= \ [Incipit ] Frase ^ Punteggiatura [ S ] ;
Incipit ::= insomma | ma lei^"," | come dire^"," | come fosse (Soggetto | Oggetto) ^ "." \
| si parlava di (Soggetto | Oggetto) ^ ":" | ma^"," [ insomma^"," ] mi permetta ( ^ "!" \ | ^ ":" | ^ "." \ )
| no^"," [ no^"," [ no^"," ] ] attenzione ^ ";" | eh ^ ( "!" | "..." ) \
| ehhhh ^ ("!" | "...") \ | mi scusi ^ (^"," | "..." \ ) | ah^"," pardon ^ "." \
| no^"," dico ^ ( "!" \ | "..." \ | ":" ) ;
Frase ::= Soggetto Verbo Azione Oggetto [^"," Inciso ^"," Frase ];
Inciso ::= ++ (in|nel) senso FiguraRetorica
| VerboGerundio (Soggetto | Oggetto) che [^"," Inciso ^"," ] (Soggetto | Oggetto) VerboImperfetto Azione (Soggetto | Oggetto) [ e Frase ];
(* --------------- componenti della frase ------------------ *)
Soggetto ::= +++ antani | tapioca | +++ supercazzola [ prematurata ]
| un gatto | +++ ComponiSbi | ComponiTapioca | ComponiTablinda
| una mucca | una pecora | un piccione | un tapiro
| un bradipo | prematurata [ la supercazzola ] | lei ;
Verbo ::= ha | e ^ "`" | ++ come fosse | fotte | frigge | succhia | soffia | mangia
| +++ (parla | disquisisce | blatera) [ AggettivoParlare ] [ di Argomenti ]
| +++ VerboInsulto (Soggetto | Oggetto) [ con AggettivoInsulto ]
| sbrodola | insignisce | paragona (Soggetto|Oggetto) con (Soggetto|Oggetto) e
| cristallizza | si infervora | ++ racconta storie | infittisce il mistero
| miagola | abbaia | +++ gioisce | ++ blinda | tira via;
VerboGerundio ::= avendo (avuto| sbrodolato| fregato| succhiato| mangiato
| +++(parlato|disquisito|blaterato) [AggettivoParlare] [di Argomenti] [con (Soggetto|Oggetto)]
| VerboInsulto ^ to (Soggetto|Oggetto) [con AggettivoInsulto]
| paragonato (Soggetto|Oggetto) con (Oggetto) | raccontato storie
| miagolato| abbaiato| prematurato| tirato via )
| essendo (stato| ^ si infervorato| nato| fritto) ;
VerboImperfetto ::= aveva | era | sbrodolava ;
VerboInsulto ::= fanculizza | infama | umilia | disprezza | cretineggia ;
Azione ::= ParticellePronominali | Posizione | insieme a
| ++ Verbo Avverbio Oggetto
| con (Soggetto | Oggetto) e Verbo Azione | soltanto con NumeroDi
| con [lo] scappellamento a (destra | sinistra) [ carpiato [all'indietro] ] ;
Oggetto ::= palle | ++ antani | ComponiTapioca | ComponiSbi | ComponiTablinda
| mucca | pecora | tapiro | bradipo | prematurata [la supercazzola]
| [la] supercazzola [prematurata] | scarpallaccia [ ^ "-" ^ allacciascarpa ]
| una cosa [da non credere|impossibile] | quintana | trinita ^ "`"
| Denari ;
(* --------------- sotto-componenti ---------------- *)
Posizione ::= sopra [a|di] | sotto [a|di] | a fianco [a|di] | dietro [a|di]
| davanti [a|di] | in mezzo [a|di] ;
AggettivoParlare ::= con ( moderazione | gioia | disgusto | apprensione | vivacita ^ "`"
| curiosita ^ "`" | disprezzo | amore | ipocrisia ) ;
AggettivoInsulto ::= moderazione | cattiveria | serieta ^ "`" | odio | amore
| stranezza | sincerita ^ "`" ;
(* --------------- "utils" ----------------- *)
Punteggiatura ::= Ex: "!" [ ^ (Punteggiatura.Ex | Punteggiatura.Quest) ]
| Quest: "?" [ ^ (Punteggiatura.Ex | Punteggiatura.Quest) ]
| +++ Norm: "." | Norm: "..." ;
ParticellePronominali ::= di | a | da | in | con [ NumeroDi ] | su | per | fra [ NumeroDi ] | tra [ NumeroDi ] ;
NumeroDi ::= un numero imprecisato di | Numero [ ^ Numero ] [ ^ Numero ] ;
Numero ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 ;
Argomenti ::= corse di ( cani | gatti | moto | \ f1 | levrieri | macchine )
| rally [in siberia | nel deserto] | fumetti | libri | tante cose
| musica [rock | classica | rap | pop | alternativa | strana]
| cantanti [rock | folk | depressi | allegri | strani ]
| scoregge | rutti | peti | piante | fiori | pollice verde
| foglie di (platano | pioppo | quercia | ulivo)
| cucina [ creativa | alternativa | vegetariana ]
| alcool | preparazione di (cocktail | bombe | attentati
| [deliziosi | ottimi] pranzetti | esami dell"'"uni )
| tante [ tante | tante tante ] cose
;
ComponiSbi ::= sbi ^ VarieI ^ gu ^ VarieI ;
ComponiTapioca ::= VarieTara ^ [ VarieTara ] ^ tapioca ;
ComponiTablinda ::= VarieTara ^ [ VarieTara ] ^ tablinda ;
VarieI ::= di | fi | li | ri | si ;
VarieTara ::= ta | ra | tara | tarata ;
Denari ::= Denaro [ ^"," Denari ] ;
Denaro ::= sterline | dollari | svanziche | rubli | lire | euri | pesetas
| franchi (svizzeri | francesi) | moneta [ forte | debole ] ;
Avverbio ::= ovviamente | adesso | gia ^ "`" | spesso | raramente
| qualche volta | attualmente | giustamente | incredibilmente ;
FiguraRetorica ::= allegorico | allusivo | anacolutico | anacronico
| anadiplotico | anaforico | analitico | antitetico
| arcaico | catacretico | connotativo | denotativo
| ellittico | enfatico | epifonemaico | inverso
| ironico | metaforico | mimetico | omoteleutico
| onomatopeico | ossimorico | paradossale
| pleonastico | sarcastico | sinestetico | topico ;
|