/usr/share/polygen/eng/manager.grm is in polygen-data 1.0.6.ds2-14build1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 | I ::= "title: New Economy manager\n"
^ "author: Manta\n"
^ "language: english\n"
^ "status: mature\n"
^ "topic: misc\n"
^ "audience: anybody\n"
^ "disclaim:" Prods and Prod are
( "Mulino Bianco" | "Barilla" | "Vodafone" | "MacDonald's"
| "Chupa & Chups" | "De Longhi" | "Ferrero" | "Burger King"
| "Calvin Klain" | "Valentino" | "Ferrari" | "Rolls Royce"
)
(^"," [limited] "inc.")
trademarks ^"\n"
^ "created: 25/08/2002"
;
Prod ::= Java | Internet
;
Prods ::= Prod [^"," Prods]
;
S ::= \Period.inf^"."
;
Period ::= we (Aux.aff Pred.(noun|adj).inf. | Either.(aff|-neg))
(---- _
| (
( 1: ^"," so that | 1: and | 1: ^"," but | 1: ^"," otherwise
| 2: ^"," thus | 2: as [(long | soon) as]
)
[1: then | 1: therefore | 1: ^"," this way^"," | 2: indeed]
).(1|2) Period.(noun|adj).
| [in order] to Pred.(noun|adj).inf.
| for Pred.(noun|adj).ing.
)
;
Either ::= (neg: n^ | aff: _) either Aux Pred.(noun|adj).inf. ^","
(neg: n^ | aff: _) or Aux Pred.(noun|adj).inf.
;
Aux ::= (should | can | could | would) [better]
| (have | need) to
| aff: will [be able to]
;
Pred ::= Verb Obj
;
Obj ::= Adjective Noun
| the (development | design) of (Genitive.adj Noun | Genitive.noun)
;
Noun ::= systems | tools | controls | applications | projects | engines
| services | providers | portals | [application] servers | solutions | strategies
| architectures | technologies | politicies
;
Adjective ::= Internet [^"-"^(based | oriented | like | native | mobile)] [Genitive]
| "on-demand" | (on | off)^"-line" | "on-the-fly"
| "out-of-the-box" | software | hardware | firmware | shareware | freeware
| public domain | net[^work] | multimedia | virtual | management
| performant | embedded | "auto-starting" | "peer-to-peer"
| visual | "fine-grained" | "loosely-coupled" | enterprise
| "e-"^("Commerce" | "Business") | owner
| integrated | interactive | globalized | computerized | informatized
;
Internet ::= "Internet" | "Net" | "Web" | "Wap" | "MMS" | "SMS" | "WWW" | "GPRS"
| "World Wide Web" | "B2B" | 3D | "B2C" | "ISDN" | "ADSL" | "Business"
| "Consumer" | ["TCP/"^]"IP" | ("PGP" | "GPG") [^"-key"]
;
Genitive ::= software
| hardware
| [Java] >(app | serv)^let (noun: ^s | adj: _)
| "Information-retrieval"
| data acquiring
| ambient (noun: ^s | adj: _)
| "Data-entr" ^ (adj: y | noun: ies)
| "Database" (noun: ^s | adj: _)
| (artificial intelligence | "AI")
| [Java] application (noun: ^s | adj: _)
| "Net-surfing"
| ("JSP" | "HTML" | "ASP" | "PHP" | "CGI"^["-bin"] | "XML") (noun: pages | adj: _)
;
Java ::= ["Enterprise"] "Java"[^"Bean"] | "J2EE" | "C++" | "C#" | ".Net" | "JMS"
| "JNDI" | "EJB" | ["Shockwave" | "Macromedia"] "Flash" | "XML"
;
Verb ::= >( [re^]implement | develop | outclass | install
| test | deploy
) (ing: ^ing | inf: _)
| >( [re^]integrat | manag | handl | maximiz | globaliz | defin | iterat
| configur | releas | monitoriz
) (inf: ^e | ing: ^ing)
| inf: >(interact with | map | debug)
| ing: >(interacting with | mapping | debugging)
;
|