/usr/share/acl2-6.3/books/str/strrpos.lisp is in acl2-books-source 6.3-5.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 | ; ACL2 String Library
; Copyright (C) 2009-2013 Centaur Technology
;
; Contact:
; Centaur Technology Formal Verification Group
; 7600-C N. Capital of Texas Highway, Suite 300, Austin, TX 78731, USA.
; http://www.centtech.com/
;
; This program is free software; you can redistribute it and/or modify it under
; the terms of the GNU General Public License as published by the Free Software
; Foundation; either version 2 of the License, or (at your option) any later
; version. This program is distributed in the hope that it will be useful but
; WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
; FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for
; more details. You should have received a copy of the GNU General Public
; License along with this program; if not, write to the Free Software
; Foundation, Inc., 51 Franklin Street, Suite 500, Boston, MA 02110-1335, USA.
;
; Original author: Jared Davis <jared@centtech.com>
(in-package "STR")
(include-book "strprefixp")
(local (include-book "arithmetic"))
; BOZO should probably rewrite this to have a nice listrpos function sort of
; thing.
(defsection strrpos-fast
:parents (strrpos)
:short "Fast implementation of @(see strrpos)."
(defund strrpos-fast (x y n xl yl)
(declare (type string x y)
(type (integer 0 *) n xl yl)
(xargs :guard (and (stringp x)
(stringp y)
(natp xl)
(natp yl)
(natp n)
(<= n (length y))
(= xl (length x))
(= yl (length y)))
:measure (nfix n)))
;; N goes from YL to 0.
(cond ((mbe :logic (prefixp (explode x)
(nthcdr n (explode y)))
:exec (strprefixp-impl (the string x)
(the string y)
(the integer 0)
(the (integer 0 *) n)
(the (integer 0 *) xl)
(the (integer 0 *) yl)))
(lnfix n))
((zp n)
nil)
(t
(strrpos-fast (the string x)
(the string y)
(the (integer 0 *) (+ -1 (lnfix n)))
(the (integer 0 *) xl)
(the (integer 0 *) yl)))))
(local (in-theory (enable strrpos-fast)))
(defthm strrpos-fast-type
(or (and (integerp (strrpos-fast x y n xl yl))
(<= 0 (strrpos-fast x y n xl yl)))
(not (strrpos-fast x y n xl yl)))
:rule-classes :type-prescription)
(defthm strrpos-fast-upper-bound
(implies (force (natp n))
(<= (strrpos-fast x y n xl yl) n))
:rule-classes :linear)
(defthm strrpos-fast-when-empty
(implies (and (not (consp (explode x)))
(equal xl (length x))
(equal yl (length y))
(natp n))
(equal (strrpos-fast x y n xl yl)
n))))
(defsection strrpos
:parents (substrings)
:short "Locate the last occurrence of a substring."
:long "<p>@(call strrpos) searches through the string @('y') for the last
occurrence of the substring @('x'). If @('x') occurs somewhere in @('y'), it
returns the starting index of the last occurrence. Otherwise, it returns
@('nil') to indicate that @('x') never occurs in @('y').</p>
<p>The function is \"efficient\" in the sense that it does not coerce its
arguments into lists, but rather traverses both strings with @(see char). On
the other hand, it is a naive string search which operates by repeatedly
calling @(see strprefixp), rather than some better algorithm.</p>
<p>Corner case: we say that the empty string <b>is</b> an prefix of any other
string. As a consequence, @('(strrpos \"\" x)') is (length x) for all
@('x').</p>"
(definlined strrpos (x y)
(declare (type string x y))
(let ((yl (length (the string y))))
(declare (type (integer 0 *) yl))
(strrpos-fast (the string x)
(the string y)
(the (integer 0 *) yl)
(the (integer 0 *) (length (the string x)))
(the (integer 0 *) yl))))
(local (in-theory (enable strrpos strrpos-fast)))
(defthm strrpos-type
(or (and (integerp (strrpos x y))
(<= 0 (strrpos x y)))
(not (strrpos x y)))
:rule-classes :type-prescription)
(encapsulate
()
(local (defthm lemma
(implies (and (stringp x)
(stringp y)
(natp xl)
(natp yl)
(natp n)
(<= n (length y))
(= xl (length x))
(= yl (length y))
(strrpos-fast x y n xl yl))
(prefixp (explode x)
(nthcdr (strrpos-fast x y n xl yl)
(explode y))))
:hints(("Goal" :induct (strrpos-fast x y n xl yl)))))
(defthm prefixp-of-strrpos
(implies (and (strrpos x y)
(force (stringp x))
(force (stringp y)))
(prefixp (explode x)
(nthcdr (strrpos x y) (explode y))))))
(encapsulate
()
(local (defun my-induction (x y n m xl yl)
(declare (xargs :measure (nfix n)))
(cond ((prefixp (explode x)
(nthcdr n (explode y)))
nil)
((zp n)
(list x y n m xl yl))
(t
(my-induction x y
(- (nfix n) 1)
(if (= (nfix n) (nfix m))
(- (nfix m) 1)
m)
xl yl)))))
(local (defthm lemma
(implies (and (stringp x)
(stringp y)
(natp xl)
(natp yl)
(natp n)
(natp m)
(>= n m)
(<= n (length y))
(= xl (length x))
(= yl (length y))
(prefixp (explode x)
(nthcdr m (explode y))))
(and (natp (strrpos-fast x y n xl yl))
(>= (strrpos-fast x y n xl yl) m)))
:hints(("Goal"
:induct (my-induction x y n m xl yl)
:do-not '(generalize fertilize)))))
(defthm completeness-of-strrpos
(implies (and (prefixp (explode x)
(nthcdr m (explode y)))
(<= m (len y))
(force (natp m))
(force (stringp x))
(force (stringp y)))
(and (natp (strrpos x y))
(>= (strrpos x y) m)))))
(defthm strrpos-upper-bound-weak
(implies (and (force (stringp x))
(force (stringp y)))
(<= (strrpos x y)
(len (explode y))))
:rule-classes ((:rewrite) (:linear)))
(encapsulate
()
(local (defthm lemma
(implies (and (stringp x)
(stringp y)
(posp xl)
(posp yl)
(natp n)
(<= n (length y))
(= xl (length x))
(= yl (length y)))
(< (strrpos-fast x y n xl yl) yl))
:hints(("Goal"
:induct (strrpos-fast x y n xl yl)))))
(defthm strrpos-upper-bound-strong
(implies (and (not (equal y ""))
(not (equal x ""))
(force (stringp x))
(force (stringp y)))
(< (strrpos x y)
(len (explode y))))
:rule-classes ((:rewrite) (:linear)))))
|