/usr/share/perl5/Debian/Debhelper/Buildsystem/qmake.pm is in debhelper 9.20120115ubuntu3.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 | # A debhelper build system class for Qt projects
# (based on the makefile class).
#
# Copyright: © 2010 Kelvin Modderman
# License: GPL-2+
package Debian::Debhelper::Buildsystem::qmake;
use strict;
use warnings;
use Debian::Debhelper::Dh_Lib qw(error);
use base 'Debian::Debhelper::Buildsystem::makefile';
our $qmake="qmake";
sub DESCRIPTION {
"qmake (*.pro)";
}
sub check_auto_buildable {
my $this=shift;
my @projects=glob($this->get_sourcepath('*.pro'));
my $ret=0;
if (@projects > 0) {
$ret=1;
# Existence of a Makefile generated by qmake indicates qmake
# class has already been used by a prior build step, so should
# be used instead of the parent makefile class.
my $mf=$this->get_buildpath("Makefile");
if (-e $mf) {
$ret = $this->SUPER::check_auto_buildable(@_);
open(my $fh, '<', $mf)
or error("unable to open Makefile: $mf");
while(<$fh>) {
if (m/^# Generated by qmake/i) {
$ret++;
last;
}
}
close($fh);
}
}
return $ret;
}
sub configure {
my $this=shift;
my @options;
my @flags;
push @options, '-makefile';
push @options, '-nocache';
if ($ENV{CFLAGS}) {
push @flags, "QMAKE_CFLAGS_RELEASE=$ENV{CFLAGS} $ENV{CPPFLAGS}";
push @flags, "QMAKE_CFLAGS_DEBUG=$ENV{CFLAGS} $ENV{CPPFLAGS}";
}
if ($ENV{CXXFLAGS}) {
push @flags, "QMAKE_CXXFLAGS_RELEASE=$ENV{CXXFLAGS} $ENV{CPPFLAGS}";
push @flags, "QMAKE_CXXFLAGS_DEBUG=$ENV{CXXFLAGS} $ENV{CPPFLAGS}";
}
if ($ENV{LDFLAGS}) {
push @flags, "QMAKE_LFLAGS_RELEASE=$ENV{LDFLAGS}";
push @flags, "QMAKE_LFLAGS_DEBUG=$ENV{LDFLAGS}";
}
push @flags, "QMAKE_STRIP=:";
push @flags, "PREFIX=/usr";
$this->doit_in_builddir($qmake, @options, @flags, @_);
}
sub install {
my $this=shift;
my $destdir=shift;
# qmake generated Makefiles use INSTALL_ROOT in install target
# where one would expect DESTDIR to be used.
$this->SUPER::install($destdir, "INSTALL_ROOT=$destdir", @_);
}
1
|