/usr/lib/ats2-postiats-0.2.9/libc/DATS/dirent.dats is in ats2-lang 0.2.9-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 | (***********************************************************************)
(* *)
(* Applied Type System *)
(* *)
(***********************************************************************)
(*
** ATS/Postiats - Unleashing the Potential of Types!
** Copyright (C) 2011-2013 Hongwei Xi, ATS Trustful Software, Inc.
** All rights reserved
**
** ATS is free software; you can redistribute it and/or modify it under
** the terms of the GNU GENERAL PUBLIC LICENSE (GPL) as published by the
** Free Software Foundation; either version 3, or (at your option) any
** later version.
**
** ATS is distributed in the hope that it will be useful, but WITHOUT ANY
** WARRANTY; without even the implied warranty of MERCHANTABILITY or
** FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
** for more details.
**
** You should have received a copy of the GNU General Public License
** along with ATS; see the file COPYING. If not, please write to the
** Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
** 02110-1301, USA.
*)
(* ****** ****** *)
//
// Author: Hongwei Xi
// Authoremail: gmhwxiATgmailDOTcom
// Start Time: March, 2013
//
(* ****** ****** *)
//
#define
ATS_DYNLOADFLAG 0 // no need for dynloading at run-time
//
#define
ATS_EXTERN_PREFIX "atslib_" // prefix for external names
//
(* ****** ****** *)
//
staload
UN =
"prelude/SATS/unsafe.sats"
//
(* ****** ****** *)
//
staload "libc/SATS/dirent.sats"
//
(* ****** ****** *)
//
implement
{}(*tmp*)
dirent$PC_NAME_MAX((*void*)) = 256
//
(* ****** ****** *)
implement
{}(*tmp*)
dirent_get_d_name_gc
(ent) = let
//
val (
fpf | str
) = dirent_get_d_name (ent)
val str2 = strptr1_copy (str)
prval () = fpf (str)
//
in
str2
end // end of [dirent_get_d_name_gc]
implement
{}(*tmp*)
direntp_get_d_name_gc
(entp) = let
//
val (
pf, fpf | p
) = direntp_get_viewptr (entp)
val str2 = dirent_get_d_name_gc<> (!p)
prval () = minus_addback (fpf, pf | entp)
//
in
str2
end // end of [direntp_get_d_name_gc]
(* ****** ****** *)
implement
{}(*tmp*)
compare_dirent_string
(ent1, str2) = sgn where
{
//
val
(
fpf1 | str1
) = dirent_get_d_name (ent1)
val sgn = compare_string_string ($UN.strptr2string(str1), str2)
prval () = fpf1 (str1)
//
} (* end of [compare_dirent_string] *)
(* ****** ****** *)
%{
extern
atstype_ptr
atslib_opendir_exn
(
atstype_string dname
) {
DIR *dirp ;
dirp = opendir((char*)dname) ;
if (!dirp) ATSLIBfailexit("opendir") ;
return dirp ; // [opendir] succeeded
} // end of [atslib_opendir_exn]
%}
(* ****** ****** *)
%{
extern
atsvoid_t0ype
atslib_closedir_exn
(
atstype_ptr dirp
) {
int err = closedir((DIR*)dirp) ;
if (err < 0) ATSLIBfailexit("closedir") ;
return ; // [closedir] succeeded
} // end of [atslib_closedir_exn]
%}
(* ****** ****** *)
implement
{}(*tmp*)
readdir_r_gc
(dirp) = let
//
val ofs = $extfcall
(
Size_t
, "offsetof"
, $extval (int, "atslib_dirent_type")
, $extval (int, "d_name")
)
//
val bsz =
ofs + i2sz(dirent$PC_NAME_MAX()+1)
//
val
[l:addr](pf, pfgc | p) = malloc_gc(bsz)
//
prval(pf) =
$UN.castview0{(dirent?)@l}(pf)
var res: ptr
val err = readdir_r (dirp, !p, res)
//
in
//
if
res > 0
then (
//
$UN.castvwtp0{Direntp1}@(pf, pfgc | p)
//
) (* end of [then] *)
else let
prval() = opt_clear{dirent}(!p)
val ((*freed*)) = ptr_free{dirent?}(pfgc, pf | p)
in
$UN.castvwtp0{Direntp0}(the_null_ptr)
end (* end of [else] *)
//
end // end of [readdir_r_gc]
(* ****** ****** *)
//
// HX-2016-07-17: Extension
//
(* ****** ****** *)
implement
{}(*tmp*)
streamize_DIRptr_dirent
(dirp) = auxmain(dirp) where
{
//
fun
auxmain
(
dirp: DIRptr1
) : stream_vt(dirent) = $ldelay
(
let
//
val x0_con =
stream_vt_cons{dirent}(_, _)
//
val+stream_vt_cons(ent, xs) = x0_con
//
var res: ptr
val err = readdir_r (dirp, ent, res)
//
in
//
if
res > 0
then let
prval() = opt_unsome(ent)
in
xs := auxmain(dirp); fold@(x0_con); x0_con
end // end of [then]
else let
prval() = opt_unnone(ent)
in
free@(x0_con); closedir_exn(dirp); stream_vt_nil((*void*))
end // end of [else]
//
end : stream_vt_con(dirent) // end of [let]
//
,
//
closedir_exn(dirp)
//
) (* end of [auxmain] *)
//
} (* end of [streamize_DIRptr_dirent] *)
(* ****** ****** *)
(* end of [dirent.dats] *)
|