/usr/share/perl5/Debian/Debhelper/Buildsystem/perl_build.pm is in debhelper 9.20120909.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 | # A build system class for handling Perl Build based projects.
#
# Copyright: © 2008-2009 Joey Hess
# © 2008-2009 Modestas Vainius
# License: GPL-2+
package Debian::Debhelper::Buildsystem::perl_build;
use strict;
use Debian::Debhelper::Dh_Lib qw(compat);
use base 'Debian::Debhelper::Buildsystem';
use Config;
sub DESCRIPTION {
"Perl Module::Build (Build.PL)"
}
sub check_auto_buildable {
my ($this, $step) = @_;
# Handles everything
my $ret = -e $this->get_sourcepath("Build.PL");
if ($step ne "configure") {
$ret &&= -e $this->get_sourcepath("Build");
}
return $ret ? 1 : 0;
}
sub do_perl {
my $this=shift;
$this->doit_in_sourcedir("perl", @_);
}
sub new {
my $class=shift;
my $this= $class->SUPER::new(@_);
$this->enforce_in_source_building();
return $this;
}
sub configure {
my $this=shift;
my @flags;
$ENV{PERL_MM_USE_DEFAULT}=1;
if ($ENV{CFLAGS} && ! compat(8)) {
push @flags, "config=optimize=$ENV{CFLAGS} $ENV{CPPFLAGS}";
}
if ($ENV{LDFLAGS} && ! compat(8)) {
push @flags, "config=ld=$Config{ld} $ENV{CFLAGS} $ENV{LDFLAGS}";
}
$this->do_perl("Build.PL", "installdirs=vendor", @flags, @_);
}
sub build {
my $this=shift;
$this->do_perl("Build", @_);
}
sub test {
my $this=shift;
$this->do_perl("Build", "test", @_);
}
sub install {
my $this=shift;
my $destdir=shift;
$this->do_perl("Build", "install", "destdir=$destdir", "create_packlist=0", @_);
}
sub clean {
my $this=shift;
if (-e $this->get_sourcepath("Build")) {
$this->do_perl("Build", "--allow_mb_mismatch", 1, "distclean", @_);
}
}
1
|