/usr/share/gap/pkg/Polycyclic/gap/action/orbstab.gi is in gap-polycyclic 2.11-3.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 | #############################################################################
##
#W orbstab.gi Polycyc Bettina Eick
##
## The orbit-stabilizer algorithm for elements of Z^d.
##
#############################################################################
##
#F CheckStabilizer( G, S, mats, v )
##
CheckStabilizer := function( G, S, mats, v )
local actS, m, R;
# first check that S is stabilizing
actS := InducedByPcp( Pcp(G), Pcp(S), mats );
for m in actS do if v*m <> v then return false; fi; od;
# now consider the random stabilizer
R := RandomPcpOrbitStabilizer( v, Pcp(G), mats, OnRight );
if ForAny( R.stab, x -> not x in S ) then return false; fi;
return true;
end;
#############################################################################
##
#F CheckOrbit( G, g, mats, e, f )
##
CheckOrbit := function( G, g, mats, e, f )
return e * InducedByPcp( Pcp(G), g, mats ) = f;
end;
#############################################################################
##
#F OrbitStabilizerTranslationAction( K, derK ) . . . . . for transl. subgroup
##
OrbitStabilizerTranslationAction := function( K, derK )
local base, gens, orbit, trans, stabl;
# the first case is that image is trivial
if ForAll( derK, x -> x = 0*x ) then
return rec( stabl := K, trans := [], orbit := [] );
fi;
# now compute orbit in standart form
gens := AsList( Pcp(K) );
base := FreeGensAndKernel( derK );
if Length( base.kern ) > 0 then
base.kern := NormalFormIntMat( base.kern, 2 ).normal;
fi;
# set up result
orbit := base.free;
trans := List( base.trsf, x -> MappedVector( x, gens ) );
stabl := List( base.kern, x -> MappedVector( x, gens ) );
return rec( stabl := stabl, trans := trans, orbit := orbit );
end;
#############################################################################
##
#F InducedDerivation( g, G, linG, derG ) . . . . . . . . . value of derG on g
##
InducedDerivation := function( g, G, linG, derG )
local pcp, exp, der, i, e, j, inv;
pcp := Pcp( G );
exp := ExponentsByPcp( pcp, g );
der := 0 * derG[1];
for i in [1..Length(exp)] do
e := exp[i];
if linG[i] = linG[i]^0 then
der := der + e*derG[i];
elif e > 0 then
for j in [1..e] do
der := der * linG[i] + derG[i];
od;
elif e < 0 then
inv := linG[i]^-1;
for j in [1..-e] do
der := (der - derG[i]) * inv;
od;
fi;
od;
return der;
end;
#############################################################################
##
#F StabilizerIrreducibleAction( G, K, linG, derG ) . . . . . . kernel of derG
##
StabilizerIrreducibleAction := function( G, K, linG, derG )
local derK, stabK, OnAffMod, affG, e, h, H, gens, i, f, k;
# catch the trivial case first
if ForAll( derG, x -> x = 0 * x ) then return G; fi;
# now we are in a non-trivial case - compute derivations of K
derK := List( Pcp(K), x -> InducedDerivation( x, G, linG, derG ) );
# compute orbit and stabilizer under K
stabK := OrbitStabilizerTranslationAction( K, derK );
Info( InfoIntStab, 3, " translation orbit: ", stabK.orbit);
# if derK = 0, then K is the kernel
if Length( stabK.orbit ) = 0 then return K; fi;
# define affine action
OnAffMod := function( pt, aff )
local im;
im := pt * aff[1] + aff[2];
return VectorModLattice( im, stabK.orbit );
end;
# use finite orbit stabilizer to determine block-stab
affG := List( [1..Length(linG)], x -> [linG[x], derG[x]] );
e := derG[1] * 0;
h := PcpOrbitStabilizer( e, Pcp(G), affG, OnAffMod ).stab;
H := SubgroupByIgs( G, h );
Info( InfoIntStab, 3, " finite orbit has length ", Index(G,H));
# now we have to compute the complement
gens := ShallowCopy( AsList( Pcp( H, K ) ) );
for i in [1..Length( gens )] do
f := InducedDerivation( gens[i], G, linG, derG );
e := MemberBySemiEchelonBase( f, stabK.orbit );
k := MappedVector( e, stabK.trans );
gens[i] := gens[i] * k^-1;
od;
Info( InfoIntStab, 3, " determined complement ");
gens := AddIgsToIgs( gens, stabK.stabl );
return SubgroupByIgs( G, gens );
end;
#############################################################################
##
#F OrbitIrreducibleActionTrivialKernel( G, K, linG, derG, v ) . v^g in derG?
##
## returns an element g in G with v^g in derG and ker(derG) if g exists.
## returns false otherwise.
##
OrbitIrreducibleActionTrivialKernel := function( G, K, linG, derG, v )
local I, d, lin, der, g, t, a, m;
# set up
I := linG[1]^0;
d := Length(I);
# compute basis of Q[G] and corresponding derivations
lin := StructuralCopy(linG);
der := StructuralCopy(derG);
while RankMat(der) < d do
g := Random(G);
t := InducedDerivation( g, G, linG, derG );
if t <> 0 * t and IsBool( SolutionMat( der, t ) ) then
Add( der, t );
Add( lin, InducedByPcp( Pcp(G), g, linG ) );
fi;
od;
# find linear combination
a := SolutionMat( der, v );
if IsBool( a ) then Error("derivations do not span"); fi;
# translate combination
m := Sum(List( [1..Length(a)], x -> a[x] * (lin[x] - I))) + I;
# check if a preimage of m is in g
g := MemberByCongruenceMatrixAction( G, linG, m );
# now return
if IsBool( g ) then return false; fi;
return rec( stab := K, prei := g );
end;
#############################################################################
##
#F OrbitIrreducibleAction( G, K, linG, derG, v ) . . . . . . . . v^g in derG?
##
## returns an element g in G with v^g in derG and ker(derG) if g exists.
## returns false otherwise.
##
OrbitIrreducibleAction := function( G, K, linG, derG, v )
local derK, stabK, I, a, m, g, OnAffMod, affG, e, h, i, c, k, H, f, gens,
found, w;
# catch some trivial cases first
if v = 0 * v then
return rec( stab := StabilizerIrreducibleAction( G, K, linG, derG ),
prei := One(G) );
fi;
if ForAll( derG, x -> x = 0 * x ) then return false; fi;
# now we are in a non-trivial case - compute derivations of K
derK := List( Pcp(K), x -> InducedDerivation( x, G, linG, derG ) );
# compute orbit and stabilizer under K
stabK := OrbitStabilizerTranslationAction( K, derK );
Info( InfoIntStab, 3, " translation orbit: ", stabK.orbit);
# if derK = 0, then K is the kernel and g is a linear combination
if Length( stabK.orbit ) = 0 then
return OrbitIrreducibleActionTrivialKernel( G, K, linG, derG, v );
fi;
# define affine action
OnAffMod := function( pt, aff )
local im;
im := pt * aff[1] + aff[2];
return VectorModLattice( im, stabK.orbit );
end;
# use finite orbit stabilizer to determine block-stab
affG := List( [1..Length(linG)], x -> [linG[x], derG[x]] );
e := derG[1] * 0;
h := PcpOrbitStabilizer( e, Pcp(G), affG, OnAffMod );
H := SubgroupByIgs( G, h.stab );
# get preimage
found := false; i := 0;
while not found and i < Length( h.orbit ) do
i := i + 1;
c := PcpSolutionIntMat( stabK.orbit, v-h.orbit[i] );
if not IsBool( c ) then
g := TransversalElement( i, h, One(G) );
w := InducedDerivation( g, G, linG, derG );
c := PcpSolutionIntMat( stabK.orbit, v-w);
k := MappedVector( c, stabK.trans );
g := g * k;
found := true;
fi;
od;
if not found then return false; fi;
# get stabilizer as complement
gens := ShallowCopy( AsList( Pcp( H, K ) ) );
for i in [1..Length( gens )] do
f := InducedDerivation( gens[i], G, linG, derG );
e := MemberBySemiEchelonBase( f, stabK.orbit );
k := MappedVector( e, stabK.trans );
gens[i] := gens[i] * k^-1;
od;
gens := AddToIgs( stabK.stabl, gens );
return rec( stab := SubgroupByIgs( G, gens ), prei := g);
end;
#############################################################################
##
#F StabilizerCongruenceAction( G, mats, e, ser )
##
StabilizerCongruenceAction := function( G, mats, e, ser )
local d, l, pcp, S, i, actS, derS, nath, subs, full, T, actT, derT,
take, natb, act, der, ref, U, K;
# catch the trivial case
if ForAll( mats, x -> e * x = e ) then return G; fi;
# set up
pcp := Pcp( G );
l := Length( ser );
S := G;
# now use induction on this series
for i in [1..l-1] do
d := Length( ser[i] ) - Length( ser[i+1] );
Info( InfoIntStab, 2, " ");
Info( InfoIntStab, 2, " consider layer ", i, " of dim ",d);
# get action of S on the full space
actS := InducedByPcp( pcp, Pcp(S), mats );
derS := List( actS, x -> e*x - e );
# induce action of mats to the current layer
nath := NaturalHomomorphismByLattices( ser[i], ser[i+1] );
actS := List( actS, x -> InducedActionFactorByNHLB( x, nath ) );
derS := List( derS, x -> ImageByNHLB( x, nath ) );
# the current layer is a semisimple S-module -- get kernel
Info( InfoIntStab, 2, " computing kernel of linear action");
K := KernelOfCongruenceMatrixAction( S, actS );
# set up for iteration
full := IdentityMat( Length(actS[1]) );
subs := [full];
# now loop over irreducible submodules and compute stab T
T := S; actT := actS; derT := derS;
ref := ( d > 1 );
while Length( subs ) > 0 do
# refine and choose module
if ref then
subs := RefineSplitting( actT, subs );
subs := List( subs, PurifyRationalBase );
fi;
Info( InfoIntStab, 2, " spaces: ", List(subs,Length));
take := Remove(subs);
# induce action to subspace if necessary
if Length( take ) < d then
natb := NaturalHomomorphismBySemiEchelonBases( full, take );
act := List(actT, x -> InducedActionSubspaceByNHSEB(x, natb));
der := List(derT, x -> ProjectionByNHSEB(x, natb));
else
act := actT;
der := derT;
fi;
# stabilize
Info( InfoIntStab, 2, " computing orbit by irreducible action");
U := StabilizerIrreducibleAction( T, K, act, der );
l := Index( T, U );
T := SubgroupByIgs( T, Cgs(U) );
# reset
ref := ( l > 1 );
if ref and Length( subs ) > 0 then
K := NormalIntersection( K, T );
actT := InducedByPcp( Pcp(S), Pcp(T), actS );
derT := List( Pcp(T),
x -> InducedDerivation(x, S, actS, derS));
fi;
# do a check
if Length( Pcp( T ) ) = 0 then return T; fi;
od;
S := T;
od;
Info( InfoIntStab, 2, " ");
return S;
end;
#############################################################################
##
#F OrbitCongruenceAction := function( G, mats, e, f, ser )
##
## returns Stab_G(e) and g in G with e^g = f if g exists.
## returns false otherwise.
##
OrbitCongruenceAction := function( G, mats, e, f, ser )
local pcp, l, S, g, i, d, actS, derS, nath, K, full, subs, T, actT, derT,
take, natb, act, der, ref, o, u;
# catch some trivial cases
if e = f then
return rec( stab := StabilizerCongruenceAction(G, mats, e, ser),
prei := One( G ) );
fi;
if RankMat( [e,f] ) = 1 or ForAll( mats, x -> e*x = e) then
return false;
fi;
# set up
pcp := Pcp( G );
l := Length( ser );
S := G;
g := One( G );
# now use induction on this series
for i in [1..l-1] do
d := Length( ser[i] ) - Length( ser[i+1] );
Info( InfoIntStab, 2, " ");
Info( InfoIntStab, 2, " consider layer ", i, " of dim ",d);
# get action of S on the full space
actS := InducedByPcp( pcp, Pcp(S), mats );
derS := List( actS, x -> e*x - e );
# induce action of mats to the current layer
nath := NaturalHomomorphismBySemiEchelonBases( ser[i], ser[i+1] );
actS := List( actS, x -> InducedActionFactorByNHSEB( x, nath ) );
derS := List( derS, x -> ImageByNHSEB( x, nath ) );
# the current layer is a semisimple S-module -- get kernel
Info( InfoIntStab, 2, " computing kernel of linear action");
K := KernelOfCongruenceMatrixAction( S, actS );
# set up for iteration
full := IdentityMat( Length(actS[1]) );
subs := [full];
# now loop over irreducible submodules and compute stab T
T := S; actT := actS; derT := derS;
ref := ( d > 1 );
while Length( subs ) > 0 do
# refine and choose module
if ref then
subs := RefineSplitting( actT, subs );
subs := List( subs, PurifyRationalBase );
fi;
Info( InfoIntStab, 2, " spaces: ", List(subs,Length));
take := Remove(subs);
# set up element and do a check
u := f * InducedByPcp( pcp, g, mats )^-1 - e;
if Length(Pcp(T)) = 0 and u = 0*u then
return rec( stab := T, prei := g );
elif Length(Pcp(T)) = 0 then
return false;
fi;
u := ImageByNHSEB( u, nath );
# induce action to subspace if necessary
if Length( take ) < d then
natb := NaturalHomomorphismBySemiEchelonBases( full, take );
act := List(actT, x -> InducedActionSubspaceByNHSEB(x, natb));
der := List(derT, x -> ProjectionByNHSEB(x, natb));
u := ProjectionByNHSEB( u, natb );
else
act := actT;
der := derT;
fi;
# find preimage h with u = h^der if it exists
Info( InfoIntStab, 2, " computing orbit by irreducible action");
o := OrbitIrreducibleAction( T, K, act, der, u );
if IsBool(o) then return false; fi;
# reset
ref := ( Index( T, o.stab ) > 1 );
g := o.prei * g;
if ref and Length( subs ) > 0 then
T := SubgroupByIgs(G, Cgs(o.stab));
K := NormalIntersection( K, T );
actT := InducedByPcp( Pcp(S), Pcp(T), actS );
derT := List(Pcp(T), x -> InducedDerivation(x, S, actS, derS));
fi;
od;
S := T;
od;
Info( InfoIntStab, 2, " ");
return rec( stab := S, prei := g );
end;
#############################################################################
##
#F FindPosition( orbit, pt, K, actK, orbfun )
##
FindPosition := function( orbit, pt, K, actK, orbfun )
local j, k;
for j in [1..Length(orbit)] do
k := orbfun( K, actK, pt, orbit[j] );
if not IsBool( k ) then return j; fi;
od;
return false;
end;
#############################################################################
##
#F ExtendOrbitStabilizer( e, K, actK, S, actS, orbfun, op )
##
## K has finite index in S and and orbfun solves the orbit problem for K.
##
ExtendOrbitStabilizer := function( e, K, actK, S, actS, orbfun, op )
local gens, rels, mats, orbit, trans, trels, stab, i, f, j, n, t, s, g;
# get action
gens := Pcp(S,K);
rels := RelativeOrdersOfPcp( gens );
mats := InducedByPcp( Pcp(S), gens, actS );
# set up
orbit := [e];
trans := [];
trels := [];
stab := [];
# construct orbit and stabilizer
for i in Reversed( [1..Length(gens)] ) do
# get new point
f := op( e, mats[i] );
j := FindPosition( orbit, f, K, actK, orbfun );
# if it is new, add all blocks
n := orbit;
t := [];
s := 1;
while IsBool( j ) do
n := List( n, x -> op( x, mats[i] ) );
Append( t, n );
j := FindPosition( orbit, op( n[1], mats[i]), K, actK, orbfun );
s := s + 1;
od;
# add to orbit
Append( orbit, t );
# add to transversal
if s > 1 then
Add( trans, gens[i]^-1 );
Add( trels, s );
fi;
# compute stabiliser element
if rels[i] = 0 or s < rels[i] then
g := gens[i]^s;
if j > 1 then
t := TransversalInverse(j, trels);
g := g * SubsWord( t, trans );
fi;
f := op( e, InducedByPcp( Pcp(S), g, actS ) );
g := g * orbfun( K, actK, f, e );
Add( stab, g );
fi;
od;
return rec( stab := Reversed( stab ), orbit := orbit,
trels := trels, trans := trans );
end;
#############################################################################
##
#F StabilizerModPrime( G, mats, e, p )
##
StabilizerModPrime := function( G, mats, e, p )
local F, t, S;
F := GF(p);
t := InducedByField( mats, F );
S := PcpOrbitStabilizer( e*One(F), Pcp(G), t, OnRight );
return SubgroupByIgs( G, S.stab );
end;
#############################################################################
##
#F StabilizerIntegralAction( G, mats, e ) . . . . . . . . . . . . . Stab_G(e)
##
# FIXME: This function is documented and should be turned into a GlobalFunction
StabilizerIntegralAction := function( G, mats, e )
local p, S, actS, K, actK, T, stab, ser, orbf;
# reduce e
e := e / Gcd( e );
# catch the trivial case
if ForAll( mats, x -> e*x = e ) then return G; fi;
# compute modulo 3 first
S := G;
actS := mats;
for p in USED_PRIMES@ do
Info( InfoIntStab, 1, "reducing by stabilizer mod ",p);
T := StabilizerModPrime( S, actS, e, p );
Info( InfoIntStab, 1, " obtained reduction by ",Index(S,T));
S := T;
actS := InducedByPcp( Pcp(G), Pcp(S), mats );
od;
# use congruence kernel
Info( InfoIntStab, 1, "determining 3-congruence subgroup");
K := KernelOfFiniteMatrixAction( S, actS, GF(3) );
actK := InducedByPcp( Pcp(G), Pcp(K), mats );
Info( InfoIntStab, 1, " obtained subgroup of index ",Index(S,K));
# compute homogeneous series
Info( InfoIntStab, 1, "computing module series");
ser := HomogeneousSeriesOfRationalModule( mats, actK, Length(e) );
ser := List( ser, x -> PurifyRationalBase(x) );
# get Stab_K(e)
Info( InfoIntStab, 1, "adding stabilizer for congruence subgroup");
T := StabilizerCongruenceAction( K, actK, e, ser );
# set up orbit stabilizer function for K
orbf := function( K, actK, a, b )
local o;
o := OrbitCongruenceAction( K, actK, a, b, ser );
if IsBool(o) then return o; fi;
return o.prei;
end;
# compute block stabilizer
Info( InfoIntStab, 1, "constructing block orbit-stabilizer");
stab := ExtendOrbitStabilizer( e, K, actK, S, actS, orbf, OnRight );
Info( InfoIntStab, 1, " obtained ",Length(stab.orbit)," blocks");
stab := AddIgsToIgs( stab.stab, Igs(T) );
stab := SubgroupByIgs( G, stab );
# do a temporary check
if CHECK_INTSTAB@ then
Info( InfoIntStab, 1, "checking results");
if not CheckStabilizer(G, stab, mats, e) then
Error("wrong stab in integral action");
fi;
fi;
# now return
return stab;
end;
#############################################################################
##
#F OrbitIntegralAction( G, mats, e, f ) . . . . . . . . . . . . . . .e^g = f?
##
## returns Stab_G(e) and g in G with e^g = f if g exists.
## returns false otherwise.
##
# FIXME: This function is documented and should be turned into a GlobalFunction
OrbitIntegralAction := function( G, mats, e, f )
local c, F, t, os, j, g, S, actS, K, actK, ser, orbf, h, T, l;
# reduce e and f
c := Gcd(e); e := e/c; f := f/c;
if not ForAll( f, IsInt ) or AbsInt(Gcd(f)) <> 1 then return false; fi;
# catch some trivial cases
if e = f then
return rec( stab := StabilizerIntegralAction(G, mats, e),
prei := One( G ) );
fi;
if RankMat( [e,f] ) = 1 or ForAll( mats, x -> e*x = e) then
return false;
fi;
# compute modulo 3 first
Info( InfoIntStab, 1, "reducing by orbit-stabilizer mod 3");
F := GF(3);
t := InducedByField( mats, F );
os := PcpOrbitStabilizer( e*One(F), Pcp(G), t, OnRight );
j := Position( os.orbit, f*One(F) );
if IsBool(j) then return false; fi;
# extract infos
g := TransversalElement( j, os, One(G) );
l := f * InducedByPcp( Pcp(G), g, mats )^-1;
S := SubgroupByIgs( G, os.stab );
actS := InducedByPcp( Pcp(G), Pcp(S), mats );
# use congruence kernel
Info( InfoIntStab, 1, "determining 3-congruence subgroup");
K := KernelOfFiniteMatrixAction( S, actS, F );
actK := InducedByPcp( Pcp(G), Pcp(K), mats );
# compute homogeneous series
Info( InfoIntStab, 1, "computing module series");
ser := HomogeneousSeriesOfRationalModule( mats, actK, Length(e) );
ser := List( ser, x -> PurifyRationalBase(x) );
# set up orbit stabilizer function for K
orbf := function( K, actK, a, b )
local o;
o := OrbitCongruenceAction( K, actK, a, b, ser );
if IsBool(o) then return o; fi;
return o.prei;
end;
# determine block orbit and stabilizer
Info( InfoIntStab, 1, "constructing block orbit-stabilizer");
os := ExtendOrbitStabilizer( e, K, actK, S, actS, orbf, OnRight );
# get orbit element and preimage
j := FindPosition( os.orbit, l, K, actK, orbf );
if IsBool(j) then return false; fi;
h := TransversalElement( j, os, One(G) );
l := l * InducedByPcp( Pcp(S), h, actS )^-1;
g := orbf( K, actK, e, l ) * h * g;
# get Stab_K(e) and thus Stab_G(e)
Info( InfoIntStab, 1, "adding stabilizer for congruence subgroup");
T := StabilizerCongruenceAction( K, actK, e, ser );
t := AddIgsToIgs( os.stab, Igs(T) );
T := SubgroupByIgs( T, t );
# do a temporary check
if CHECK_INTSTAB@ then
Info( InfoIntStab, 1, "checking results");
if not CheckStabilizer(G, T, mats, e) then
Error("wrong stab in integral action");
elif not CheckOrbit(G, g, mats, e, f) then
Error("wrong orbit in integral action");
fi;
fi;
# now return
return rec( stab := T, prei := g );
end;
|